« Previous entry | Next entry » Browse > Snippets

Skip to comments (1) IWMP Kill List
Posted by guest on Jan 02 2007 @ 15:22  :: 3291 unique visits

;==============================================
; Script Name: IWMP Kill List
; Author: iwantmypot
; Version: 1.00b
; Client Tested with: 5.0.1j
; EUO version tested with: 1.5v69
; Shard OSI / FS: OSI
; Revision Date: 3/29/06
; Public Release: 3/24/06
; Global Variables Used: none
; Purpose: Create a list of all non-friend players near you
; Thanks to: a_goat for the idea/inspiration to create this script.
;==============================================
set %guildtag [****] , #spc , $
set %buttonheight 15
set %buttondistance 2
;==============================================
set %enemies 1_4_5_6
set %creatures _
set %ignored _
set #menubutton none
set %buttons 0
set #lpc 1000
gosub menu
begin:
gosub search
finditem * G
if #findcnt = 0 && #menubutton = none
 goto begin
if #findcnt = 0 && #menubutton <> none
 goto thebuttons
for #findindex 1 #findcnt
 {
 if ( #findrep = 3 || #findrep = 0 )
    {
    set %creatures %creatures , #findtype , _
    continue
    }
 event property #findid
 if #findrep in %enemies && %guildtag notin #property && (bonded) notin #property && (tame) notin #property && #findid <> #charid
   {
   gosub addbutton #findid #property #findrep #findtype
   continue
   }
 if #findrep notin %enemies && #findrep <> 7
   set %creatures %creatures , #findtype , _
 else
   set %ignored %ignored , #findid , _
 }
if #menubutton = none
 goto begin
thebuttons:
if target in #menubutton
 {
 str del #menubutton 1 6
 gosub bersaglio #strres
 }
if friend in #menubutton
 {
 str del #menubutton 1 6
 set %ignored %ignored , %tid . #strres , _
 }
if remove in #menubutton
 {
 str del #menubutton 1 6
 set %creatures %creatures , %type . #strres , _
 }
if #menubutton = reset
 {
 set %creatures _
 set %ignored _
 }
if #menubutton = CLOSED
  halt
set #menubutton none
goto begin

;------------SUBS--------------------------------

sub bersaglio
 {
 menu get melee
 set #ltargetid %tid . %1
 set #ltargetkind 1
 event macro 22 0
 if #menures
    event macro 27 0
 return
 }

sub addbutton
 {
 set %tid . %buttons %1
 str pos %2 $
 set %left #strres - 1
 str left %2 %left
 set %name . %buttons #strres
 set %rep . %buttons %3
 set %type . %buttons %4
 set %down ( %buttonheight + %buttondistance ) * %buttons
 if #findrep = 1
   menu Font BGColor Aqua
 if #findrep = 4
   menu Font BGColor Gray
 if #findrep = 5
   menu Font BGColor $000080FF
 if #findrep = 6
   menu Font BGColor $003838DE
 menu Button target , %buttons 0 %down 130 %buttonheight %name . %buttons
 menu Font BGColor BtnFace
 menu Button friend , %buttons 135 %down 25 %buttonheight F
 menu Button remove , %buttons 160 %down 25 %buttonheight X
 set %buttons %buttons + 1
 ignoreitem %1
 return
 }

sub remove
 {
 set %buttons %buttons - 1
 set %2 %buttons - 1
 for %mover %1 %2
   {
   if %1 > %2
      break
   set %temp %mover + 1
   set %tid . %mover %tid . %temp
   set %name . %mover %name . %temp
   set %rep . %mover %rep . %temp
   set %type . %mover %type . %temp
   if %rep . %mover = 1
     menu Font BGColor Aqua
   if %rep . %mover = 4
     menu Font BGColor Gray
   if %rep . %mover = 5
     menu Font BGColor $000080FF
   if %rep . %mover = 6
     menu Font BGColor $003838DE
   menu delete target , %mover
   set %down ( %buttonheight + %buttondistance ) * %mover
   menu Button target , %mover 0 %down 130 %buttonheight %name . %mover
   menu Font BGColor BtnFace
   }
 menu delete target , %buttons
 menu delete friend , %buttons
 menu delete remove , %buttons
 return
 }

sub search
 {
 if %buttons = 0
    return
 ignoreitem reset
 ignoreitem %ignored , %creatures
 set %limit %buttons - 1
 for %sfm %limit 0
   {
   finditem %tid . %sfm G
   if #findcnt = 0
     {
     gosub remove %sfm
     continue
     }
   event property #findid
   str pos #property $
   set %left #strres - 1
   str left #property %left
   if %name . %sfm <> #strres || #findrep <> %rep . %sfm
     gosub remove %sfm
   else
     ignoreitem %tid . %sfm
   }
 return
 }

;------------MENU--------------------------------

Sub Menu
 {
 menu Clear
 menu Window Title Kill List
 menu Window Color Black
 menu Window Size 185 #CLIYRES    ;<-- WINDOW SIZE
 menu Font Transparent #true
 menu Font Align Right
 menu Font Name Arial
 menu Font Size 8
 menu Font Style
 menu Font Color WindowText
 set %down #cliyres - 25
 menu Font Color Silver
 menu Font Align Left
 menu Font BGColor Black
 menu Check melee 5 %down 150 25 #false Auto-Attack
 menu Font Color WindowText
 menu Font BGColor BtnFace
 menu Button reset 160 %down 25 25 R
 menu Show #CLIXRES -3
 menu Show #CLIXRES -3
 menu HideEUO
 return
 }

1 comment posted so far
Add your own »